dialog spc {
  title "Spell"
  size -1 -1 79 69
  option dbu
  box "Enter 1 Word To Check:", 1, 2 2 76 20
  edit "", 2, 4 10 48 9, autohs left
  button "Check", 3, 54 10 22 9, flat
  box "Outcome", 4, 2 23 76 45
  list 5, 4 32 48 34, size vsbar
  button "Clear", 6, 54 32 22 9, flat
  button "Copy", 7, 54 44 22 9, flat
  button "Exit", 8, 54 56 22 9, flat ok
}
on *:load: { 
  echo 12 -a You Have Just Loaded Napa182's SpellChecker Dialog
  echo 12 -a A Script0rs Inc. Production 
  echo -a 14,1(14,1¯15,1¯0,1¯0,1º $+($chr(171),$chr(164),$chr(88),$chr(167),$chr(199),$chr(174),$chr(238),$chr(254),$chr(116),$chr(48),$chr(174),$chr(167),$chr(88),$chr(164),$chr(187)) º0,1¯15,1¯14,1¯) $+ $chr(153)
}
alias spc { dialog $iif($dialog(spc),-v,-md) spc spc }
menu menubar,channel {
  .Spell Checker:{ spc }
}
alias -l oops { didtok spc 5 32 Word Not Found }
alias -l lookup { if (!%temp) { did -r spc 5 | $oops } | else { did -ra spc 5 Maybe Try: | didtok spc 5 32 %temp } }
on *:dialog:spc:init:0:{ did -b spc 3,6,7 }
on *:dialog:spc:edit:2:{ 
  did -e spc 3,6,7 
  if ($chr(32) isin $did(2).text) || ($did(2).text !isalpha) { did -r spc 2 | noop $input(Please Enter Only One Word No Space's And No Numbers,uho,ERROR!) }
}
on *:dialog:spc:sclick:*: {
  if ($did == 3) {
    if ($sock(spell)) .sockclose spell
    set %cksp $did(2).text
    sockopen spell www.spellcheck.net 80
  }
  if ($did == 6) { did -r spc 2,5 | did -b spc 3,6,7 }
  if ($did == 7) { clipboard $did(5).seltext }
}
on *:SOCKOPEN:spell: {
  sockwrite -nt $sockname GET /cgi-bin/spell.exe?action=CHECKWORD&string= $+ %cksp HTTP/1.1
  sockwrite -nt $sockname Host: www.spellcheck.net
  sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:spell: {
  if ($sockerr) { did -ra spc 5 Socket Error }
  else {
    var %spck
    sockread %spck
    if (*correctly* iswm %spck) {  
      did -r spc 5  
      didtok spc 5 32 %cksp Is Right
      sockclose $sockname
      unset %cksp
    }
    elseif (*</BLOCKQUOTE>* iswm %spck) { 
      $lookup
      sockclose $sockname
      unset %temp %cksp
    }
    else { noop $regex(%spck,/(.+)<BR>/i) | set %temp $addtok(%temp,$regml(1),32) }
  }
}